Device drivers aren't supported by the DOS emulation. You can boot real DOS in DOSBox, but then your ISO file will have to be contained on an HDD image.

Why not use IMGMOUNT to mount the ISO directly? DOSBox internally emulates a CD-ROM device driver and MSCDEX, so there's no need to load them.

I'm aware that Dosbox provides CDROM emulation and this works fine for most purposes.

In my case I am setting up a large directory tree of installed and configured games which I want to be able to dropped on to a HDD or CF in one of my real dos systems (as well as work in Dosbox), so using internal tools like imgmount in the bat files which will launch any games that run from an iso on that filesystem is a non starter.

I could write all of the iso-based game start scripts to use imgmount calls, but then I'd have to bulk convert all of those bat files when finished with something like sed or perl to replace imgmount calls with the various pairings of shsucdhd and shsucdx commands. That feels dirty to have to do things twice and not be able to test from the relative comfort of Dosbox.

If the shsucd* virtual CDROM driver utilities don't work with Dosbox, that seems pretty clear that it's a dead end to do that work from within that environment though.

Since you're mounting an ISO either way, you could do it by calling a batch file with parameters, and then you'd only need to change that one batch file depending on the system.

You can also do conditional processing within batch files, such as: IF EXISTS Z:\COMMAND.COM GOTO DOSBOX

That's a great idea. I'll have a look at writing a wrapper script around imgmount and shsucdx.

Okay, these two wrappers should accomplish what I need - host agnostic mounting and unmounting of ISO images:

ISOMOUNT.BAT:

1@ECHO OFF
2SET ISODIR=D:\ISO
3SET ISODRIVE=E
4SET DOSBOXDRIVE=Z:
5SET SHSPATH=C:\TOOLS\SHSUCD
6
7IF EXIST %ISODIR%\%1 GOTO CHECKBOX
8GOTO MISSING
9
10:CHECKBOX
11REM -= Mount an ISO =-
12@echo Mounting ISO file %ISODIR%\%1 as %ISODRIVE%
13IF EXIST %DOSBOXDRIVE%\COMMAND.COM GOTO DOSBOX
14GOTO REALBOX
15
16:REALBOX
17REM -= Mount an ISO using shscudhd/shsucdx =-
18@echo Calling SHSCUDHD
19%SHSPATH%\SHSCUDHD /F:%ISODIR%\%1 /Q
20@echo Calling SHSUCDX
21%SHSPATH%\SHSUCDX /D:SHSU-CDH,%ISODRIVE% /Q
22GOTO END
23
24:DOSBOX
25REM -= Mount an ISO using Dosbox imgmount =-
26REM @echo Calling Dosbox imgmount
27%DOSBOXDRIVE%\imgmount %ISODRIVE%: %ISODIR%\%1 -t iso -fs iso
28GOTO END
29
30:MISSING
31REM -= ISO is missing =-
32@echo Warning! The source ISO %ISODIR%\%1 is missing
33@echo ===============================================
34@echo You must call this tool with the name of an ISO file
35@echo which is available in %ISODIR%
36@echo e.g. ISOMOUNT.BAT TENTACLE.ISO
37GOTO END
38
39:END
40REM -= End of ISO mount wrapper =-

ISOUMNT.BAT:

1@ECHO OFF
2SET ISODIR=D:\ISO
3SET ISODRIVE=E
4SET DOSBOXDRIVE=Z:
5SET SHSPATH=C:\TOOLS\SHSUCD
6
7:CHECKBOX
8REM -= Unmount an ISO =-
9@echo Unmounting ISO file on %ISODRIVE%
10IF EXIST %DOSBOXDRIVE%\COMMAND.COM GOTO DOSBOX
11GOTO REALBOX
12
13:REALBOX
14REM -= Unmount an ISO using shscudhd/shsucdx =-
15@echo Calling SHSCUDHD to unload
16%SHSPATH%\SHSCUDHD /U /Q
17@echo Calling SHSUCDX to unload
18%SHSPATH%\SHSUCDX /U /Q
19GOTO END
20
21:DOSBOX
22REM -= Unmount an ISO using Dosbox imgmount =-
23@echo Calling Dosbox imgmount to unload
24%DOSBOXDRIVE%\imgmount -u %ISODRIVE%:
25GOTO END
26
27:END
28REM -= End of ISO mount wrapper =-

To mount an ISO using either imgmount or the shs drivers, called as follows:
ISOMOUNT <NAME_OF_ISO_IN_YOUR_ISODIR>

To unmount a currently mounted ISO image, called without any arguments:
ISOUMNT

This gets me where I need to be, so I can start writing game launchers by using these wrappers to load and unload ISO images without being concerned of the underlying tools of the platform (real vs dosbox) underneath it.

Obviously this is based on my use case of having a single ISO directory with all of my image files. If you have them in individual folders then you'll maybe want to adjust the file path check and alter a few of the directories. Consider the two batch files CC licensed as per the attachments to this message.