Right, I got this off another site, did another reinstall of SotHR using it and the game worked on my XP Pro SP3 dual core AMD 5600 2gb DDR2 6200 ram Realtek soundcard system. I did install it on a drive formatted in FAT32. (I have included the .BAT file as an attachment for those worried about copying/pasting, just un-RAR it anywhere and double click on it.)

open notepad and paste the following code (between the lines).
save as "whshr.bat" with quotes
then double click the whshr.bat
to have the game installed from the CD

-------------------------------------------------------------------------------------------
@echo off
title S.o.t.h.r. Install Helper
color 4E

rem 12/18/07 check for cmdext before executing script
VERIFY OTHER 2>nul
SETLOCAL ENABLEEXTENSIONS
IF ERRORLEVEL 1 echo Unable to enable command extensions (cmd.exe /E:ON)
IF ERRORLEVEL 1 goto end


echo.
echo Warhammer: Shadow of the Horned Rat (English v1.1)
echo Install Helper (for win 2k, xp, vista) Freeware, No Warranties
echo Created by aqrit
echo.
echo Full Install (340mb) No CD needed to play
echo.
echo example path [ C:\games\Warhammer - sothr ]
set /p installto=Install To Path:
echo.
echo example path [ D: ]
set /p installfrom=Install From Path:
echo.
echo Wait for notification of installation completion before closing
pause

xcopy /s /y "%installfrom%\WARFB\REMOTE\*.*" "%installto%\*.*"
xcopy /s /y "%installfrom%\WARFB\ENG\FILE\*.*" "%installto%\*.*"
mkdir "%installto%\SAVE"
copy "%installfrom%\WARFB\ENG\WIN95\*.*" "%installto%\*.*"
copy "%installfrom%\WARFB\ENG\GENERIC\*.*" "%installto%\*.*"
copy "%installfrom%\RMORPH\RLDDF.DLL" "%installto%\*.*"
xcopy /s /y "%installfrom%\RMORPH\RL\*.*" "%windir%\system32\RL\*.*"
copy "%installfrom%\WING\WING32.DLL" "%windir%\system32\*.*"

echo.
echo Creating Registry Entries...
rem double backslash needed in *.reg file
set installtodub=%installto%
set installtodub=%installtodub:\=\\%
echo Windows Registry Editor Version 5.00 >"%installto%\WHSHR.REG"
echo. >>"%installto%\WHSHR.REG"
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Mindscape] >>"%installto%\WHSHR.REG"
echo. >>"%installto%\WHSHR.REG"
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Mindscape\WarHammerFB] >>"%installto%\WHSHR.REG"
echo. >>"%installto%\WHSHR.REG"
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Mindscape\WarHammerFB\LocalDir] >>"%installto%\WHSHR.REG"
echo @="%installtodub%" >>"%installto%\WHSHR.REG"
echo. >>"%installto%\WHSHR.REG"
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Mindscape\WarHammerFB\RemoteDir] >>"%installto%\WHSHR.REG"
echo @="%installtodub%" >>"%installto%\WHSHR.REG"
echo. >>"%installto%\WHSHR.REG"
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Mindscape\WarHammerFB\SaveDir] >>"%installto%\WHSHR.REG"
echo @="SAVE" >>"%installto%\WHSHR.REG"
echo. >>"%installto%\WHSHR.REG"
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Mindscape\WarHammerFB\UpdateDir] >>"%installto%\WHSHR.REG"
echo @="" >>"%installto%\WHSHR.REG"
echo.
start /d %windir% /wait regedit /s "%installto%\WHSHR.REG"

echo Installation Finished
echo.
echo Windows Vista might have the sothr fonts "in-use" and not allow sothr
echo to use them... if this happens just restart your pc
:end
pause

---------------------------------------------------------------------------------------------

I chose win95, 640x480, 256 colour in the right click/compatibility options for the WHSHR.exe, double clicked it and game worked fine! Didn't need a slow down program or anything else. So with the above installer, for me anyway, it was 'install and play' - hope it helps y'all on your PC's! 😀