TSR-Programming/Assembler: Why do i need a Keypress under Dosbox on releasing TSR Memory? \ VOGONS

TSR-Programming/Assembler: Why do i need a Keypress under Dosbox on releasing TSR Memory?

Topic actions

First post, by llm

Posted on 2021-11-16, 16:50

llm Offline

Rank Member

Rank: Member
Posts: 289
Joined: 2009-01-18, 16:57

FYI: this is my very first DOS TSR after >30Years
its a reduced example of my NoUniVBE project that just contains my TSR install/uninstall

the program installs a TSR that hooks Interrupt 10h (doing nothing currently) and
uses some Interrupt 10h relative Data to finde itself for uninstalling (UniVBE does is alike and the detection Data will be much larger in the end)

i detect if the TSR is installed, recover the original int 10h vector entry and
free the memory with int 21h/49h

The attachment tsr.png is no longer available

the problem is that after calling int 21h/49h dosbox waits for a kexpress (i think there is something very wrong in my code that produces this effect)
and the original int 10h seems to be not recovered after the uninstall because my install detection matches again

any idea?

1; USAM or MASM
2; uasm.exe tsrint10.asm
3
4; ulink.exe -T16 -Tdc tsrint10.obj, tsrint10.com,tsrint10.map
5; or 16bit link.exe from microsoft
6
7.MODEL TINY
8
9PSP_BYTES = 100h
10
11Far_pointer struc
12  offs dw 0
13  segm dw 0
14Far_pointer ends
15
16TSR_ID_STR EQU <"MyID">
17
18TSR_info_t struc
19  signature db TSR_ID_STR
20  load_segment dw 0
21  old_int10h Far_pointer<>
22TSR_info_t ends
23
24.CODE
25
26org PSP_BYTES
27
28start:
29
30jmp configure
31
32;====================================================
33; resident part
34;====================================================
35
36tsr_info TSR_info_t<>
37
38; resident code
39
40detoured_int10h:
41  pushf
42  call cs:tsr_info.old_int10h
43  iret
44
45end_of_resident:
46
47;====================================================
48; configure part (not resident)
49;====================================================
50
51PARAGRAPH_BYTES = 16
52
53RESIDENT_BYTES = end_of_resident - start
54RESIDENT_PARAGRAPHS = (PSP_BYTES + RESIDENT_BYTES + (PARAGRAPH_BYTES-1))/PARAGRAPH_BYTES
55
56TSR_INFO_DISTANCE = detoured_int10h - tsr_info
57
58VIDEO_BIOS_INT = 10h ; 5h for testing
59
60

…Show last 103 lines

61; configure data
62
63installed_msg db 'installed!',10,13,'$'
64uninstalled_msg db 'uninstalled!',10,13,'$'
65
66; configure code
67
68configure:
69
70  ; is TSR installed
71  mov ah,35h
72  mov al,VIDEO_BIOS_INT
73  cli
74  int 21h
75  sti
76 
77  mov di,bx
78  sub di,TSR_INFO_DISTANCE
79  ; es:di = tsr_info
80  
81  ; exists TSR info signature?
82  cld
83  mov cx, sizeof(TSR_info_t.signature)
84  mov si, offset(tsr_info.signature)
85  repe cmpsb
86  jne install
87
88  jmp uninstall
89  
90install:
91  ; safe old VIDEO BIOS interrupt handler ptr
92  mov ah,35h
93  mov al,VIDEO_BIOS_INT
94  cli
95  int 21h
96  sti
97  mov [tsr_info.old_int10h.segm],es
98  mov [tsr_info.old_int10h.offs],bx
99
100  ; install new handler
101  mov ah,25h
102  mov al,VIDEO_BIOS_INT
103  push ds
104  push cs
105  pop ds
106  mov dx,offset(detoured_int10h)
107  cli
108  int 21h
109  sti
110  pop ds
111
112  ; safe load segment of TSR
113  mov [tsr_info.load_segment],cs
114  
115  mov dx,offset(installed_msg)
116  mov ah,9h
117  int 21h
118  
119  ; stay resident
120  mov dx,RESIDENT_PARAGRAPHS
121  mov ah,31h
122  mov al,0
123  int 21h 
124  
125uninstall:
126  mov ah,35h
127  mov al,VIDEO_BIOS_INT
128  cli
129  int 21h
130  sti
131 
132  ; es:di = tsr_info
133  mov di,bx
134  sub di,TSR_INFO_DISTANCE
135
136  ; install old handler
137  mov ah,25h
138  mov al,VIDEO_BIOS_INT
139  push ds
140  mov ax,es:[di+TSR_info_t.old_int10h.segm]
141  mov ds,ax
142  mov dx,es:[di+TSR_info_t.old_int10h.offs]
143  cli
144  int 21h
145  sti
146  pop ds
147
148  mov ah,49h
149  mov ax,es:[di+TSR_info_t.load_segment]
150  mov es,ax
151  int 21h
152; <<<<<<<<<<<<<<<<<< Dosbox waits here for a keypress?
153;<<<<<<<<<<<<<<<<<< and the recover of the old int 10h seems to not happen
154
155  mov dx,offset(uninstalled_msg)
156  mov ah,9h
157  int 21h
158  
159  mov ax,4c00h
160  int 21h
161
162end start

Reply 1 of 8, by retardware

Posted on 2021-11-16, 18:27

retardware Offline

Rank Oldbie

Rank: Oldbie
Posts: 1063
Joined: 2019-01-30, 02:00
Location: Cottbus, Germany

I have no idea why you call INT 21h with random AH contents.

And, you might want to use Soft-ICE with its convenient breakpoints to debug.

Reply 2 of 8, by llm

Posted on 2021-11-16, 19:46

llm Offline

Rank Member

Rank: Member
Posts: 289
Joined: 2009-01-18, 16:57

retardware wrote on 2021-11-16, 18:27:

I have no idea why you call INT 21h with random AH contents.

no 16 bit dos assembler work in the last 30 years - my spider sense wasn't tingling at all looking at that lines

retardware wrote on 2021-11-16, 18:27:

And, you might want to use Soft-ICE with its convenient breakpoints to debug.

im now using the dosbox debugger

thanks for the finding:

changed the code to

1  
2mov ax,es:[di+TSR_info_t.load_segment]
3mov es,ax
4mov ah,49h
5int 21h

it still needs sometimes a keypress before uninstall
but maybe there is another bug like the one you've found

The attachment tsr.png is no longer available

attached is the current version source+com file

Reply 3 of 8, by llm

Posted on 2021-11-16, 20:24

llm Offline

Rank Member

Rank: Member
Posts: 289
Joined: 2009-01-18, 16:57

found it! thanks @retardware

1  ; install old handler
2  mov ah,25h
3  mov al,VIDEO_BIOS_INT
4  push ds
5  mov ax,es:[di+TSR_info_t.old_int10h.segm]
6  mov ds,ax
7  mov dx,es:[di+TSR_info_t.old_int10h.offs]
8  cli
9  int 21h
10  sti
11  pop ds

second time trashing ah/al before int 21h call

Reply 4 of 8, by jakethompson1

Posted on 2021-11-16, 20:38

jakethompson1 Offline

Rank l33t

Rank: l33t
Posts: 2025
Joined: 2015-11-17, 04:16

Might want to free your environment segment from the initial launch before going resident to save a little memory? I don't remember off-hand if you might be leaking it.
Don't think you need the wrapping cli/sti when asking DOS to replace int10h. I think that is the reason to let DOS do it rather than messing with the IVT yourself.
I wouldn't personally use all the structs and such but that's just me, instead use equ for things like .-tsr_info
Should be able to use les bx,[tsr_info.old_int10h] if you want to try that, too

Reply 5 of 8, by retardware

Posted on 2021-11-16, 21:24

retardware Offline

Rank Oldbie

Rank: Oldbie
Posts: 1063
Joined: 2019-01-30, 02:00
Location: Cottbus, Germany

One of the projects I want to do when I got time is updating my DOS screensaver for Win95/98.
I'll upload the source when I backed up my old backups onto my new computer. Lots of CDs and HDDs.
I have forgotten how I exactly did the resident test, but it was using the code itself as signature. No need for signature strings.
It also captured the video interrupt, as optionally output turns on screen again.
But the most funny thing was the battle with the MS mouse driver, as that one always stole the mouse interrupt so my TSR had to put itself back into the mouse interrupt chain again and again.
Like two cats alternately pulling the food bowl to them 😀

Anyway, does anybody know how to check whether Windows 9x is running in the graphics mode?
This might also be of interest for llm, as some video-handling TSRs should not activate when Windows is running.

Reply 6 of 8, by jakethompson1

Posted on 2021-11-16, 21:34

jakethompson1 Offline

Rank l33t

Rank: l33t
Posts: 2025
Joined: 2015-11-17, 04:16

retardware wrote on 2021-11-16, 21:24:

Anyway, does anybody know how to check whether Windows 9x is running in the graphics mode?
This might also be of interest for llm, as some video-handling TSRs should not activate when Windows is running.

Windows will make INT 2F calls that you can hook to know when it loads and exits. http://mirror.cs.msu.ru/oldlinux.org/Linux.ol … tml/rb-4498.htm
It's more thoroughly documented in Unauthorized Windows 95

Reply 7 of 8, by llm

Posted on 2021-11-17, 08:44

llm Offline

Rank Member

Rank: Member
Posts: 289
Joined: 2009-01-18, 16:57

jakethompson1 wrote on 2021-11-16, 20:38:

Might want to free your environment segment from the initial launch before going resident to save a little memory? I don't remember off-hand if you might be leaking it.

added that - there are some document around that telling the PSP:2Ch should be freed before getting resident

jakethompson1 wrote on 2021-11-16, 20:38:

Don't think you need the wrapping cli/sti when asking DOS to replace int10h.
I think that is the reason to let DOS do it rather than messing with the IVT yourself.

removed the cli/sti

jakethompson1 wrote on 2021-11-16, 20:38:

I wouldn't personally use all the structs and such but that's just me, instead use equ for things like .-tsr_info

i've got some include files around (in my real project) that contains even the PSP as a struct 😀

jakethompson1 wrote on 2021-11-16, 20:38:

Should be able to use les bx,[tsr_info.old_int10h] if you want to try that, too

yepp

lds dx,es:[di+TSR_info_t.old_int10h]

is much better to read

Reply 8 of 8, by llm

Posted on 2021-11-17, 08:48

llm Offline

Rank Member

Rank: Member
Posts: 289
Joined: 2009-01-18, 16:57

retardware wrote on 2021-11-16, 21:24:

I have forgotten how I exactly did the resident test, but it was using the code itself as signature. No need for signature strings.

nice idea - will try to adapt that

retardware wrote on 2021-11-16, 21:24:

Anyway, does anybody know how to check whether Windows 9x is running in the graphics mode?
This might also be of interest for llm, as some video-handling TSRs should not activate when Windows is running.

i don't need that currently (i hope) im just overloading the oem-string that the VESA info returns

Go to top of page Go to top of page

Back to General Old Hardware