I'm not sure if anyone else might find this useful, but I developed this because it was useful to me. Like many, I'm sure, I have games or applications which require certain drivers or TSRs loaded before executing (i.e. network stack, VBE driver, SoftMPU, etc.) that I don't want to necessarily always load on system startup so that they always take up precious memory. Yes, I could have different startup configurations, driven by a config.sys menu system, but I personally don't care for that. I would rather load things dynamically as I need them.

Obviously the easiest way is to create a batch file to load the game which also loads the required TSR/driver (e.g. a DUKE3D.BAT which loads the S3VBE20 driver, then executes DUKE3D.EXE), but my problem with that basic method is that I could have multiple games that use the same TSR/driver, and/or if I run the same game multiple times, that means attempting to load the TSR/driver multiple times. Of course, this usually isn't a problem, as the TSRs/drivers are usually smart enough to recognize that they're already loaded in memory and just quit gracefully with some sort of error message, but for some reason that still wasn't good enough for me. I wanted a method to load a (set of) TSR/drivers on demand after boot, but also only once since last system boot.

So, without further ado, the Require-Once batch script (REQUIRE1.BAT):

1@ECHO OFF
2
3IF NOT [%1]==[] GOTO check_dirs
4
5echo.
6echo Require1 Usage: REQUIRE1 command [options]
7echo   command can be either:
8echo   clean  - (literal string) to initialize Require1 (call from AUTOEXEC.BAT)
9echo   {batch command name}  - name of a batch file in %REQUIRE_ONCE% directory
10echo                           (without .BAT extension) to be called only once
11echo                           since REQUIRE1 is called with "clean"
12echo   options can be:
13echo   quiet  - (literal string) don't announce stuff
14echo.
15echo Example:
16echo   Assuming C:\DOS\REQUIRE1\NETWORK.BAT exists, Require1 can be called as
17echo   follows to call the script only once since Require1 was last called with
18echo   the "clean" command:
19echo.
20echo   REQUIRE1 NETWORK
21echo.
22GOTO end
23
24:check_dirs
25IF [%TEMP%]==[] SET TEMP=C:\TEMP
26IF [%REQUIRE_ONCE%]==[] SET REQUIRE_ONCE=C:\DOS\REQUIRE1
27IF NOT EXIST %TEMP%\NUL MKDIR %TEMP%
28
29IF NOT [%1]==[clean] GOTO regular_execute
30
31:clean_up
32IF NOT [%2]==[quiet] ECHO Initializing Require1. Deleting temp files.
33IF EXIST %TEMP%\*.R1 DEL %TEMP%\*.R1
34GOTO end
35
36:regular_execute
37IF EXIST %REQUIRE_ONCE%\%1.BAT GOTO command_ok
38IF NOT [%2]==[quiet] ECHO Command Batch Not Found.
39GOTO end
40
41:command_ok
42IF EXIST %TEMP%\%1.R1 GOTO subsequent_run
43
44:first_run
45IF NOT [%2]==[quiet] ECHO First run for %1. Running batch.
46CALL %REQUIRE_ONCE%\%1.BAT
47ECHO 1 > %TEMP%\%1.R1
48GOTO end
49
50:subsequent_run
51IF NOT [%2]==[quiet] ECHO Subsequent run for %1. Batch command not run.
52GOTO end
53
54:end
55

It essentially works by creating temporary .R1 files as markers to note that a particular script has been run already and, as noted in the usage output, the script expects to be run with the 'clean' parameter on boot to delete any .R1 temporary files left over from last time, leaving a clean slate.

To go along with this, then, you might have a script like this (C:\DOS\REQUIRE1\S3VBE.BAT):

1@ECHO OFF
2C:\DOS\DRIVERS\S3VBE20 /INSTALL

and then (DUKE3D.BAT):

1@ECHO OFF
2CALL C:\DOS\REQUIRE1\REQUIRE1.BAT S3VBE
3DUKE3D.EXE

It is by no means thoroughly tested, but it seems to work well for my needs (on MS-DOS 6.22). Anyway, I had fun making it if only for the thought exercise, and hopefully it's handy to someone else too.