The character patterns are stored in ROM (read-only memory), so you can't write to it. You will have to copy the patterns (with your modifications) into writeable memory (RAM) and then point the INT 1Fh vector there. It should work nicely to have the writeable memory in the resident portion of a TSR. 😉

I got a little further, but it still doesn't quite work:

1DEFINT A-Z
2
3TYPE RegTypeX
4 ax AS INTEGER
5 bx AS INTEGER
6 cx AS INTEGER
7 dx AS INTEGER
8 bp AS INTEGER
9 si AS INTEGER
10 di AS INTEGER
11 flags AS INTEGER
12 ds AS INTEGER
13 es AS INTEGER
14END TYPE
15
16CONST EXTENDEDCHARACTERS = &H1F
17
18DECLARE SUB DisplayExtendedCharacters ()
19DECLARE SUB INTERRUPTX (intnum AS INTEGER, inreg AS RegTypeX, outreg AS RegTypeX)
20
21DIM Registers AS RegTypeX
22SCREEN 1
23CLS
24
25Buffer$ = STRING$(&H0, 16384)
26
27Registers.ax = &H2500 OR EXTENDEDCHARACTERS
28Registers.dx = SADD(Buffer$)
29Registers.ds = VARSEG(Buffer$)
30INTERRUPTX &H21, Registers, Registers
31
32DisplayExtendedCharacters
33
34SUB DisplayExtendedCharacters
35 FOR Character = 128 TO 255
36  PRINT CHR$(Character);
37 NEXT Character
38END SUB

The buffer only needs to be 1024 bytes (128 x 8), and if you set all the bytes to zero then the characters will all be blank like a null or space character.

@ripsaw8080: I forgot to mention that blanking the characters was my intent, which should happen with my code even though the buffer is too large. I also forgot to mention I get scrambled characters instead of blanks when displaying them.

1024 bytes eh? I calculated 16 x 8 x 128 assuming the characters used 16 scanlines each and forgot that the 8 columns were represented by bits instead of bytes. Duh.

Got it:

1DEFINT A-Z
2
3TYPE RegTypeX
4 ax AS INTEGER
5 bx AS INTEGER
6 cx AS INTEGER
7 dx AS INTEGER
8 bp AS INTEGER
9 si AS INTEGER
10 di AS INTEGER
11 flags AS INTEGER
12 ds AS INTEGER
13 es AS INTEGER
14END TYPE
15
16CONST EXTENDEDCHARACTERS = &H1F
17
18DECLARE SUB DisplayExtendedCharacters ()
19DECLARE SUB INTERRUPTX (intnum AS INTEGER, inreg AS RegTypeX, outreg AS RegTypeX)
20
21DIM Registers AS RegTypeX
22SCREEN 1
23CLS
24
25Buffer$ = STRING$(1024, 255)
26
27Registers.ax = &H2500 OR EXTENDEDCHARACTERS
28Registers.dx = SADD(Buffer$)
29Registers.ds = VARSEG(Buffer$)
30INTERRUPTX &H21, Registers, Registers
31
32DisplayExtendedCharacters
33
34SUB DisplayExtendedCharacters
35 FOR Character = 128 TO 255
36  PRINT CHR$(Character);
37 NEXT Character
38END SUB

Alright, I made a program that can retrieve and set the extended character set (see below). It can invert the font data and works fine for EGA/VGA. It also works for CGA except when trying to invert the characters. Anyone know why? The numeric parameter for GetFonts/SetFonts is a Boolean flag indicating whether CGA is used. (0 = CGA, and any other value = EGA/VGA)

1DEFINT A-Z
2
3TYPE RegTypeX
4 ax AS INTEGER
5 bx AS INTEGER
6 cx AS INTEGER
7 dx AS INTEGER
8 bp AS INTEGER
9 si AS INTEGER
10 di AS INTEGER
11 flags AS INTEGER
12 ds AS INTEGER
13 es AS INTEGER
14END TYPE
15
16CONST CGA = &H1F
17CONST EGAVGA = &H43
18CONST SIZECGA = &H400
19CONST SIZEEGAVGA = &H1000
20
21DECLARE FUNCTION GetFonts$ (IsCGA)
22DECLARE FUNCTION InvertFonts$ (Fonts$)
23DECLARE SUB DisplayExtendedCharacters ()
24DECLARE SUB INTERRUPTX (intnum AS INTEGER, inreg AS RegTypeX, outreg AS RegTypeX)
25DECLARE SUB SetFonts (IsCGA, Fonts$)
26
27SCREEN 12
28CLS
29
30Fonts$ = GetFonts$(0)
31Fonts$ = InvertFonts$(Fonts$)
32SetFonts 0, Fonts$
33
34DisplayExtendedCharacters
35
36SUB DisplayExtendedCharacters
37 FOR Character = 128 TO 255
38  PRINT CHR$(Character);
39 NEXT Character
40END SUB
41
42FUNCTION GetFonts$ (IsCGA)
43DIM Registers AS RegTypeX
44
45 IF IsCGA THEN
46  Registers.ax = &H3500 OR CGA
47  Size = SIZECGA
48 ELSE
49  Registers.ax = &H3500 OR EGAVGA
50  Size = SIZEEGAVGA
51 END IF
52
53 INTERRUPTX &H21, Registers, Registers
54
55 DEF SEG = Registers.es
56 Fonts$ = ""
57 FOR Position = Registers.bx TO Registers.bx + Size
58  Fonts$ = Fonts$ + CHR$(PEEK(Position))
59 NEXT Position
60

61GetFonts$ = Fonts$
62END FUNCTION
63
64FUNCTION InvertFonts$ (Fonts$)
65 Inverted$ = Fonts$
66 FOR Position = 1 TO LEN(Fonts$)
67  MID$(Inverted$, Position, 1) = CHR$(&HFF XOR ASC(MID$(Inverted$, Position, 1)))
68 NEXT Position
69
70 InvertFonts$ = Inverted$
71END FUNCTION
72
73SUB SetFonts (IsCGA, Fonts$)
74DIM Registers AS RegTypeX
75
76 IF IsCGA THEN
77  Registers.ax = &H2500 OR CGA
78 ELSE
79  Registers.ax = &H2500 OR EGAVGA
80 END IF
81
82 Registers.dx = SADD(Fonts$)
83 Registers.ds = VARSEG(Fonts$)
84 INTERRUPTX &H21, Registers, Registers
85END SUB

CGA and Hercules cards do have a character generator ROM, but it is only visible to the card and not to the CPU, and in text mode fonts can only be modified by replacing the ROM chip. The Hercules Plus adds definable fonts, but that card is not emulated by DOSBox.

An 8x8 font for characters 00h-7Fh is stored in system ROM at F000h:FA6Eh in 100% compatible BIOSes, and in CGA and Hercules that table will always be used for drawing the lower half of the character set in graphics modes, but the table pointed at by INT 1Fh is used for the upper half of the character set (128-255). So, for CGA and Hercules, only the upper half of the characters can be modified and only in graphics modes.

No, I am not trying to change the ROM. I copy the ROM and modify the pointer at vector 1Fh to point to the copy. Besides this page: http://helppc.netcore2k.net/interrupt/int-1f states: "can be used to change character fonts in CGA graphics mode". Just copying appears to work, it's the inverting that doesn't appear to be working properly.

The INT 1Fh table should be 1024 bytes for CGA, EGA, and VGA. INT 43h is the pointer that doesn't exist for CGA, which is for the lower half of the character set that is also 1024 bytes in size. When you put both halves of the set together is it 256 x 8 = 2048 bytes, and in EGA/VGA the tables are sequential in the video ROM, but for CGA the lower half is at the specific address I mentioned before.

BTW, AFAIK, SCREEN 12 does not work in CGA.

@ripsaw8080:
Oops, I posted code meant for VGA.

Change this:

1SCREEN 12
2CLS
3
4Fonts$ = GetFonts$(0)
5Fonts$ = InvertFonts$(Fonts$)
6SetFonts 0, Fonts$

to:

1SCREEN 1
2CLS
3
4Fonts$ = GetFonts$(-1)
5Fonts$ = InvertFonts$(Fonts$)
6SetFonts -1, Fonts$

I am using a 1024 byte buffer for CGA - and I intend to only change characters 128-255.

Well, rather than debugging your program for you, let me assure you that DOSBox will use the INT 1Fh vector to draw characters 128-255 in graphics mode even for the CGA machine type. 😉

@ripsaw8080: first of all, thank you for replying to my posts so far. I don't expect you to debug my program for me if you don't want to, however I was hoping someone (be it you or anyone else) would be willing to try to debug my code. I should have mentioned I had tried to debug my code but got stuck. I am not one (at least I think so) to immediately run to a forum at the first error trying to get someone else to fix my problems for me. I usually only make posts like these when I am really at a loss.

In short:
Noone has to debug my stuff for me at all, unless they really feel like it. I don't expect or want that. I only ask for help when I feel I am truly stuck.

Well, I had looked at your code, but nothing struck me as being incorrect except the SCREEN 12 for CGA, so I figured the problem would be something less than obvious that requires debugging.

Anyway, I pasted your code with the modifications for CGA into a .BAS file and ran it in QB 4.5 (with /l command line switch to load QB.QLB for the INTERRUPTX function), and this is a capture of the screen in DOSBox 0.74-3 (looks the same in SVN) with the machine=cga setting:

It seems to work as expected, at least to my understanding of what you expected...

@ripsaw8080:
I checked again. It works, that is the first time around. (try running it multiple times) After that the characters get corrupted. I have no idea why. Do you (or anyone else) has any idea why?

Likely because you don't set the INT 1Fh vector to point back to the characters in ROM before your program ends, so on subsequent runs you copy from where your font variable was located on the previous run, which won't necessarily be the exact same address for each run.

Of course you should always set the vector back to ROM when your program returns to DOS, because the memory for your "custom" font has been returned to the system as free memory.

@ripsaw8080:
D'oh! You're right of course, silly me. I fixed it so it now restores the original vector. And guess what? It works! Thank you!